PADS生成bom脚本

qiangqaz · 发表于 2018-6-26 18:44

EDA365欢迎您！

您需要登录才可以下载或查看，没有帐号？注册

x

pads生成bom时，无法达到自己的预期，所以干脆自己写吧，但是，我不会

linxiwell · 发表于 2018-6-27 11:59

EDA_BOMHelper花式出BOM,总有满足你的。

qiangqaz · 发表于 2018-6-26 18:45

网上找了一个
Dim fn As String

Sub Main
fn = ActiveDocument
If fn = "" Then
      fn = "Untitled"
End If

tempFile = DefaultFilePath & "\temp.txt"
Open tempFile For Output As #1
item = 0
StatusBarText = "Generating report..."
Print #1, "ITEM";vbTab;"Part Type"; vbTab;"P/N_1"; vbTab;"Manufacturer_1_P/N"; vbTab;"Description"; vbTab;"Manufacturer_1"; vbTab; "Value"; vbTab; "QTY"; vbTab; "REF-DES"
For Each pkg in ActiveDocument.PartTypes
      'Print #1, pkg.Name; vbTab; note
      qty = 0
      value = ""
      description = ""
      manufacturer = ""
      pn = ""
      manufacturerpn = ""
      symbol = ""
      item = item + 1
      'Print #1, item; vbTab;
      For Each part In pkg.Components
         value = AttrValue(part, "Value")
         description = AttrValue(part, "Description")
         manufacturer = AttrValue(part, "Manufacturer_1")
         pn = AttrValue(part, "P/N_1")
         value = AttrValue(part, "Value")
         manufacturerpn = AttrValue(part, "Manufacturer_1_P/N")
         sysid = AttrValue(part, "SYSID")
         qty = qty+1
         symbol = symbol + part.Name + ", "
      Next
      symbol_len = Len(symbol)
      symbol = Mid(symbol,1, symbol_len - 2)
      Print #1, item; vbTab; part.PartType ; vbTab; pn ; vbTab;manufacturerpn; vbTab;description; vbTab;manufacturer; vbTab;value; vbTab; qty; vbTab; symbol;
      Print #1
Next pkg
StatusBarText = ""
Close #1
ExportToExcel
End Sub

Sub ExportToExcel
FillClipboard
Dim xl As Object
On Error Resume Next
Set xl =  GetObject(,"Excel.Application")
On Error GoTo ExcelError ' Enable error trapping.
If xl Is Nothing Then
      Set xl =  CreateObject("Excel.Application")
End If
xl.Visible = True
xl.Workbooks.Add
xl.ActiveSheet.Paste
xl.Range("A1:I1").Font.Bold = True
xl.Range("A1:I1").NumberFormat = "@"
xl.Range("A1:I1").AutoFilter
xl.ActiveSheet.UsedRange.Columns.AutoFit
'Output Report Header
xl.Rows(1).Insert
xl.Rows(1).Cells(1) = Space(1) & "Part Report "& " WWZL-BOM " & " on " & Now
xl.Rows(2).Insert
xl.Rows(1).Font.bold = True
'Output Design Totals
lastRow = xl.ActiveSheet.UsedRange.Rows.Count + 1
xl.Rows(lastRow + 1).Font.bold = True
xl.Rows(lastRow + 1).Cells(1) = Space(1) & "Design Part count: " & ActiveDocument.Components.Count
xl.Range("A1").Select
On Error GoTo 0 ' Disable error trapping.
Exit Sub

ExcelError:
MsgBox Err.Description, vbExclamation, "Error Running Excel"
On Error GoTo 0 ' Disable error trapping.
Exit Sub
End Sub

Sub FillClipboard
StatusBarText = "Export Data To Clipboard..."
' Load whole file to string variable
tempFile = DefaultFilePath & "\temp.txt"
Open tempFile  For Input As #1
L = LOF(1)
AllData$ = Input$(L,1)
Close #1
'Copy whole data to clipboard
Clipboard AllData$
Kill tempFile
StatusBarText = ""
End Sub
Function AttrValue (comp As Object, atrName As String) As String
If comp.Attributes(atrName) Is Nothing Then
      AttrValue = ""
Else
      AttrValue = comp.Attributes(atrName).Value
End If
End Function

qiangqaz · 发表于 2018-6-26 18:46

一点点来吧，共勉

qiangqaz · 发表于 2018-6-26 18:48

symbol_len = Len(symbol)
symbol = Mid(symbol,1, symbol_len - 2)

这两句是个啥意思？

qiangqaz · 发表于 2018-6-26 18:52

本帖最后由 qiangqaz 于 2018-6-26 18:54 编辑

难道是数组：---
多数情况下，只需为声明的变量赋一个值。只包含一个值的变量被称为标量变量。有时候，将多个相关值赋给一个变量更为方便，因此可以创建包含一系列值的变量，称为数组变量。数组变量和标量变量是以相同的方式声明的，唯一的区别是声明数组变量时变量名后面带有括号 ( )。下例声明了一个包含 11 个元素的一维数组：

Dim A(10)
虽然括号中显示的数字是 10，但由于在 VBScript 中所有数组都是基于 0 的，所以这个数组实际上包含 11 个元素。在基于 0 的数组中，数组元素的数目总是括号中显示的数目加 1。这种数组被称为固定大小的数组。

在数组中使用索引为数组的每个元素赋值。从 0 到 10，将数据赋给数组的元素，如下所示：

A(0) = 256
A(1) = 324
A(2) = 100
. . .
A(10) = 55
与此类似，使用索引可以检索到所需的数组元素的数据。例如：

. . .
SomeVariable = A(8)
. . .
数组并不仅限于一维。数组的维数最大可以为 60（尽管大多数人不能理解超过 3 或 4 的维数）。声明多维数组时用逗号分隔括号中每个表示数组大小的数字。在下例中，MyTable 变量是一个有 6 行和 11 列的二维数组：

Dim MyTable(5, 10)
在二维数组中，括号中第一个数字表示行的数目，第二个数字表示列的数目。

qiangqaz · 发表于 2018-6-26 18:53

加两行打印，看出来个啥

      Next
      symbol_len = Len(symbol)
      Print #1,symbol_len;
      Print #1
      symbol = Mid(symbol,1, symbol_len - 2)
      Print #1, item; vbTab; part.PartType ; vbTab; pn ; vbTab;manufacturerpn; vbTab;description; vbTab;manufacturer; vbTab;value; vbTab; qty; vbTab; symbol;
      Print #1
Next pkg

qiangqaz · 发表于 2018-6-26 18:57

出来个这玩意

qiangqaz · 发表于 2018-6-29 15:43

linxiwell 发表于 2018-6-27 11:59
! s4 r# Q8 K8 }3 @) REDA_BOMHelper花式出BOM,总有满足你的。

嗯，有空研究下

		自动登录	找回密码
密码			注册

PADS生成bom脚本

EDA365欢迎您！

点评

推荐内容 /1